GUÍA DE HOJAS DE CÁLCULO

Cómo convertir horas a decimal en Excel

Para pasar horas a decimal en Excel se multiplica la celda por 24 y se le da formato de número: 7:30 son 7,50 horas. Para volver, se divide entre 24 y se aplica el formato [h]:mm, redondeando antes al minuto.

Responsable: Numalto · Actualizado el

Por qué hay que multiplicar por 24

Excel y Google Sheets guardan las horas como fracciones de día: 7:30 es 0,3125 de un día. Multiplicar por 24 convierte esa fracción en horas: 0,3125 × 24 = 7,5. Después, da a la celda formato de número con dos decimales, no de hora.

Horas Horas decimales
7:30 7,50
7:20 7,33
8:45 8,75
0:50 0,83
27:15 27,25
Para obtener Configuración española (;) Configuración inglesa (,)
Horas decimales desde A2 =A2*24 =A2*24
Horas decimales con dos cifras =REDONDEAR(A2*24;2) =ROUND(A2*24,2)
Minutos totales =A2*1440 =A2*1440

Recuerda que la parte decimal no son minutos: 0,30 h son 18 minutos y media hora se escribe 0,50 h.

Con las funciones HORA y MINUTO

Otra fórmula habitual separa las horas y los minutos y suma los minutos divididos entre 60.

Para obtener Configuración española (;) Configuración inglesa (,)
Horas decimales desde A2 =HORA(A2)+MINUTO(A2)/60 =HOUR(A2)+MINUTE(A2)/60

Funciona con horas de reloj, pero no con duraciones de más de 24 horas: HORA solo devuelve de 0 a 23 y descarta los días completos.

Horas HORA()+MINUTO()/60 ×24
7:30 7,50 7,50
23:45 23,75 23,75
27:15 3,25 27,25

Para totales semanales o mensuales, usa siempre la multiplicación por 24.

Redondear con REDONDEAR, y solo al final

El formato de número con dos decimales solo cambia lo que se ve: la celda conserva 7,3333…. La función REDONDEAR cambia el valor. Cuando sumes varias filas, suma primero las horas y redondea solo el total: redondear cada fila acumula el error.

Cinco jornadas de 7:50 Resultado
Sumar las horas (39:10) y convertir el total 39,17
Convertir cada jornada (7,83) y sumar 39,15

De decimal a horas y minutos

Para el camino inverso, divide entre 24 y aplica el formato [h]:mm. Con algunos decimales, el resultado se queda un minuto corto: el formato no redondea, corta los segundos. 7,33 h son 7 h 19,8 min, y la celda muestra 7:19. Para obtener el minuto más cercano, redondea antes:

Decimal =A2/24 con formato [h]:mm Redondeando al minuto
7,25 7:15 7:15
7,30 7:18 7:18
7,33 7:19 7:20
1,01 1:00 1:01
0,025 0:01 0:02
Para obtener Configuración española (;) Configuración inglesa (,)
Horas y minutos desde un decimal =A2/24 =A2/24
Redondeado al minuto =REDONDEAR(A2*60;0)/1440 =ROUND(A2*60,0)/1440
Redondeado al minuto, como texto =TEXTO(REDONDEAR(A2*60;0)/1440;"[h]:mm") =TEXT(ROUND(A2*60,0)/1440,"[h]:mm")

REDONDEAR lleva las mitades exactas hacia arriba: 0,025 h son 1,5 minutos y se redondean a 2.

Errores frecuentes

  • Dar formato de hora al resultado de multiplicar por 24. 7:30 × 24 es 7,5, pero con formato de hora la celda muestra 12:00. Usa formato de número.
  • Leer 7,30 h como 7 horas y 30 minutos. Son 7 h 18 min. Media hora es 0,50.
  • Usar HORA y MINUTO con totales de más de 24 horas. Pierden los días completos: 27:15 se convierte en 3,25.
  • Cortar los decimales en lugar de redondear. 1,33 h son 79,8 minutos: el minuto más cercano es 1:20, no 1:19.

Plantilla para descargar

Las fórmulas de esta guía, listas para usar: una hoja de instrucciones y otra de cálculo con las fórmulas protegidas contra borrados accidentales, sin contraseña. Archivo .xlsx sin macros para Excel o Google Sheets.